; **************************************************************************
; Name: TipiBackup
; Version: 1
; Website: http://hellotipi.com
; License: copyright © 2009 - HelloTipi SARL
; **************************************************************************
; Script write by Pierre Ammeloot - (c) 2009 HelloTipi.com
; Script generated for the HM NIS Edit Script Wizard.

BrandingText "HelloTipi.com"

; HM NIS Edit Wizard helper defines
!define PRODUCT_NAME "TipiBackup"
!define PRODUCT_VERSION "beta 3"
!define PRODUCT_PUBLISHER "HelloTipi"
!define PRODUCT_WEB_SITE "http://www.hellotipi.com"
!define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
!define PRODUCT_UNINST_ROOT_KEY "HKLM"

Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
OutFile "Install.exe"
InstallDir "$PROGRAMFILES\HelloTipi\TipiBackup"
ShowInstDetails show
ShowUnInstDetails show

; MUI 1.67 compatible ------
!include "MUI.nsh"

; MUI Settings
!define MUI_ABORTWARNING
!define MUI_ICON "img\TB-32.ico" ;TB-24.ico
!define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\modern-uninstall.ico"

!define MUI_FINISHPAGE_SHOWREADME "tipibackup.jar"  ;Modification du script pour lancer un JAR
!define MUI_FINISHPAGE_SHOWREADME_TEXT "Lancer TipiBackup"

!define MUI_WELCOMEFINISHPAGE_BITMAP "${NSISDIR}\Contrib\Graphics\Wizard\orange.bmp"

; Welcome page
!insertmacro MUI_PAGE_WELCOME
; License page
!insertmacro MUI_PAGE_LICENSE "license.txt"
; Directory page
!insertmacro MUI_PAGE_DIRECTORY
; Instfiles page
!insertmacro MUI_PAGE_INSTFILES
; Finish page
!insertmacro MUI_PAGE_FINISH
; Uninstaller pages
!insertmacro MUI_UNPAGE_INSTFILES

; Language files
!insertmacro MUI_LANGUAGE "French"

; MUI end ------

; Definitions for Java 1.6 Detection
!define JRE_VERSION "1.6"
!define JRE_URL "http://javadl.sun.com/webapps/download/AutoDL?BundleId=18714&/jre-6u5-windows-i586-p.exe"

; START Functions
Function GetJRE
;  MessageBox MB_OK "${PRODUCT_NAME} uses Java ${JRE_VERSION}, it will now be downloaded and installed."
;  MessageBox MB_OK "${PRODUCT_NAME} utilise Java ${JRE_VERSION}, il va être téléchargé et installé."
  MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "${PRODUCT_NAME} utilise Java ${JRE_VERSION}. Voulez vous télécharger la dernière version de Java et l'installer ?" IDYES +2
  Quit

  StrCpy $2 "$TEMP\Java Runtime Environment.exe"
  nsisdl::download /TIMEOUT=30000 ${JRE_URL} $2
  Pop $R0 ;Get the return value
    StrCmp $R0 "success" +3
;    MessageBox MB_OK "Download failed : $R0"
    MessageBox MB_OK "Téléchargement impossible : $R0"
    Quit
  ExecWait $2
  Delete $2
FunctionEnd

Function DetectJRE
  ReadRegStr $2 HKLM "SOFTWARE\JavaSoft\Java Runtime Environment" "CurrentVersion"
  StrCmp $2 ${JRE_VERSION} done
  Call GetJRE
  done:
FunctionEnd
; END Functions

Section "SectionPrincipale" SEC01
  Call DetectJRE
  SetOutPath "$INSTDIR"
  SetOverwrite ifnewer
  File "tipibackup.jar"
  File "license.txt"
  File "lisez-moi.txt"
  SetOutPath "$INSTDIR\lib\"
  File "lib\jdom.jar"
  SetOutPath "$INSTDIR\img\"
  File "img\TB-16.png"
  File "img\TB-64.png"
  File "img\TB-64b.png"
  File "img\TB-16.ico"
;  File "img\TB-24.ico"
  File "img\TB-32.ico"
  File "img\TB-64.ico"
  
  ;Write file TipiBackup.conf
  FileOpen $4 "$INSTDIR\TipiBackup.conf" w
  FileWrite $4 "$PICTURES"
  FileClose $4
SectionEnd

Section -AdditionalIcons
  SetOutPath $INSTDIR
  WriteIniStr "$INSTDIR\${PRODUCT_NAME}.url" "InternetShortcut" "URL" "${PRODUCT_WEB_SITE}"
  ;Icon in start menu
  CreateDirectory "$SMPROGRAMS\TipiBackup"

  CreateShortCut "$SMPROGRAMS\TipiBackup\TipiBackup.lnk" "$INSTDIR\tipibackup.jar" \
  "" "$INSTDIR\img\TB-16.ico" 0 SW_SHOWNORMAL "" "TipiBackup"
  CreateShortCut "$SMPROGRAMS\Démarrage\TipiBackup.lnk" "$INSTDIR\tipibackup.jar" \
  "" "$INSTDIR\img\TB-16.ico" 0 SW_SHOWNORMAL "" "TipiBackup"
  
  CreateShortCut "$SMPROGRAMS\TipiBackup\License.lnk" "$INSTDIR\license.txt"
  CreateShortCut "$SMPROGRAMS\TipiBackup\Website.lnk" "$INSTDIR\${PRODUCT_NAME}.url" \
  "" '$SYSDIR\SHELL32.dll' 13 SW_SHOWNORMAL "" "HelloTipi.com"
  CreateShortCut "$SMPROGRAMS\TipiBackup\Uninstall.lnk" "$INSTDIR\uninst.exe"
  ;Icon in desktop
  CreateShortCut "$DESKTOP\TipiBackup.lnk" "$INSTDIR\tipibackup.jar"  \
  "" "$INSTDIR\img\TB-64.ico" 0 SW_SHOWNORMAL "" "TipiBackup"
SectionEnd

Section -Post
  WriteUninstaller "$INSTDIR\uninst.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\img\TB-16.ico"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
  ;lancement auto au démarrage de Windows
;  WriteRegStr "HKCU" "Software\Microsoft\Windows\CurrentVersion\Run" "TipiBackup" "$INSTDIR\tipibackup.jar"
SectionEnd

Function un.onUninstSuccess
  HideWindow
  MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) a été désinstallé avec succès de votre ordinateur."
FunctionEnd

Function un.onInit
  MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "Êtes-vous certains de vouloir désinstaller totalement $(^Name) et tous ses composants ?" IDYES +2
  Abort
FunctionEnd

Section Uninstall
  Delete "$INSTDIR\${PRODUCT_NAME}.url"
  Delete "$INSTDIR\uninst.exe"
  Delete "$INSTDIR\img\TB-16.png"
  Delete "$INSTDIR\img\TB-64.png"
  Delete "$INSTDIR\img\TB-64b.png"
  Delete "$INSTDIR\img\TB-16.ico"
;  Delete "$INSTDIR\img\TB-24.ico"
  Delete "$INSTDIR\img\TB-32.ico"
  Delete "$INSTDIR\img\TB-64.ico"
  Delete "$INSTDIR\lib\jdom.jar"
  Delete "$INSTDIR\license.txt"
  Delete "$INSTDIR\lisez-moi.txt"
  Delete "$INSTDIR\tipibackup.jar"
;  Delete "$INSTDIR\TipiBackup.conf"
  Delete "$INSTDIR\TipiBackup.log"
  Delete "$INSTDIR\configuration.xml"
;  Delete "$INSTDIR\gestion.xml"

  Delete "$SMPROGRAMS\TipiBackup\TipiBackup.lnk"
  Delete "$SMPROGRAMS\Démarrage\TipiBackup.lnk"
  Delete "$SMPROGRAMS\TipiBackup\License.lnk"
  Delete "$SMPROGRAMS\TipiBackup\Uninstall.lnk"
  Delete "$SMPROGRAMS\TipiBackup\Website.lnk"
  
  Delete "$DESKTOP\TipiBackup.lnk"

  RMDir "$SMPROGRAMS\TipiBackup"
  RMDir "$INSTDIR\lib\"
  RMDir "$INSTDIR\img\"
  RMDir "$INSTDIR"

;  DeleteRegValue HKCU "Software\Microsoft\Windows\CurrentVersion\Run" "TipiBackup"
  DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
  SetAutoClose true
SectionEnd